divert(-1)
#
# Copyright (c) 1983 Eric P. Allman
# Copyright (c) 1988, 1993
#	The Regents of the University of California.  All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
# 1. Redistributions of source code must retain the above copyright
#    notice, this list of conditions and the following disclaimer.
# 2. Redistributions in binary form must reproduce the above copyright
#    notice, this list of conditions and the following disclaimer in the
#    documentation and/or other materials provided with the distribution.
# 3. All advertising materials mentioning features or use of this software
#    must display the following acknowledgement:
#	This product includes software developed by the University of
#	California, Berkeley and its contributors.
# 4. Neither the name of the University nor the names of its contributors
#    may be used to endorse or promote products derived from this software
#    without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
# ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
# IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
# ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
# FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
# DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
# OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
# HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
# LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
# OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
# SUCH DAMAGE.
#

#
#  This is a generic configuration file for FreeBSD 4.X and later systems.
#  If you want to customize it, copy it to a name appropriate for your
#  environment and do the modifications there.
#
#  The best documentation for this .mc file is:
#  /usr/share/sendmail/cf/README or
#  /usr/src/contrib/sendmail/cf/README
#
# The Cyrus v2 realtime user check procedure is documented at
# http://anfi.homeunix.net/sendmail/rtcyrus2.html

divert(0)
VERSIONID(`ECS Solaris/Cyrus/LDAP 1.0')
OSTYPE(solaris8)
DOMAIN(generic)

dnl allow cyrus to send vacation and forwarding messages without
dnl having sendmail complain
define(`confTRUSTED_USERS',`cyrus')

dnl some basics
FEATURE(access_db, `hash -o -T<TMPF> /etc/mail/access')
FEATURE(blacklist_recipients)
FEATURE(local_lmtp)
FEATURE(mailertable, `hash -o /etc/mail/mailertable')
FEATURE(virtusertable, `hash -o /etc/mail/virtusertable')

dnl the second-generation realtime cyrus user check -- uses 8.13.x's
dnl socketmap feature to talk to cyrus' smmapd to determine if mailbox
dnl exists and is deliverable
FEATURE(`ckuser_cyrus')

dnl LDAP routing and alias files
MASQUERADE_AS(`example.edu')
define(`confLDAP_CLUSTER', `ECS')
define(`confLDAP_DEFAULT_SPEC',`-h ldap.example.edu -b dc=example,dc=edu -d cn=ldap-search -P /etc/mail/ldappass')
define(`ALIAS_FILE', `ldap:-k (&(objectClass=mailGroup)(mail=%0)) -v mgrpRFC822MailMember')
FEATURE(`ldap_routing', `ldap -1 -T<TMPF> -b dc=example,dc=edu -v mailHost -k (&(objectClass=mailrecipient)(mail=%0))',`ldap -1 -T<TMPF> -b dc=example,dc=edu -v mailRoutingAddress -k (&(objectClass=mailrecipient)(mail=%0))',`reject',`preserve')
LDAPROUTE_DOMAIN(`example.edu')
LDAPROUTE_EQUIVALENT_FILE(`/etc/mail/ldap-route-domains')

dnl other host names that we accept as "local"
define(`confCW_FILE', `-o /etc/mail/local-host-names')

dnl daemon definitions: we don't let sendmail do it's default MSA so
dnl that we can define the M=Ea (a=require auth) for the submission port (587)
dnl no need for IPv6 right now
FEATURE(`no_default_msa')
DAEMON_OPTIONS(`Name=MTA, Port=smtp, M=E')
DAEMON_OPTIONS(`Name=MSA, Port=587, M=Ea')

dnl SMTP AUTH definitions: we allow LOGIN and PLAIN
define(`confAUTH_OPTIONS', `A')
TRUST_AUTH_MECH(`LOGIN PLAIN')
define(`confAUTH_MECHANISMS', `LOGIN PLAIN')

dnl more basics
define(`confBIND_OPTS', `WorkAroundBrokenAAAA')
define(`confMAX_MIME_HEADER_LENGTH', `256/128')
define(`confNO_RCPT_ACTION', `add-to-undisclosed')
define(`confPRIVACY_FLAGS', `authwarnings,noexpn,novrfy')

dnl the local mailer is the cyrusv2 realtime patch
define(`confLOCAL_MAILER', `cyrusv2')
MAILER(smtp)
MAILER(`cyrusv2')

dnl the local rulesets here allow any IP address (or classed domain block)
dnl listed in the access database with RELAY or OK to send mail OR anything
dnl that has provided a recognized authentication (LOGIN or PLAIN) as defined
dnl in TRUST_AUTH_MECH.

LOCAL_RULESETS
SLocal_check_mail
R$*			$: $1 $| $>"local_trusted_auth_mech" $1
R$* $| $#$*		$#$2
R$* $| $*		$: $1 $| $>"noauth_map" $1
R$* $| $#$*		$#$2

Slocal_trusted_auth_mech
R$*			$: $1 $| $>"Local_Relay_Auth" $&{auth_type}
R$* $| $# $*		$# $2
R$* $| NO		$: $1
R$* $| $*		$: $1 $| $&{auth_type}
R$* $|			$1
R$* $| $={TrustAuthMech}	$# RELAY

dnl this looks up the client IP address in the access database
dnl using the A ruleset which allows for class-based subnet matches
Snoauth_map
R$*			$: $&{client_addr}
R$+			$: $>A <$1> <?> <+ Connect> <$1>
R<$={Accept}> <$*>	$@ $1
R$*			$#error $@ 5.7.0 $: "530 Local authentication required."